:: ConfigPCNameTo-xxx-xxx.cmd - Créer par Tlem le 20/02/2016
:: ConfigPCNameTo-xxx-xxx est un Batch qui permet de configurer
:: automatiquement le nom et le groupe de travail du PC.
:: Batch testé sous Windows Vista, 7, 8.x et 10
::
:: Configurez les paramètres ci-dessous. Si NewWorkgroup est vide,
:: le groupe de traivail par défaut sera "Workgroup".

@Echo Off
Cls

::========================================
::      Paramètres
::========================================
Set Newcomputername=P720
Set NewWorkgroup=WORKGROUP
::========================================
::========================================

:: Code de demande d'élévation des droits.
:---------------------------------------------------------------------------------------------------------------
:GetAdminRight
:---------------------------------------------------------------------------------------------------------------
REM --> Contrôle des permissions (Version 29/02/2016).
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> Si erreur, pas de droits Admin ...
If '%errorlevel%' NEQ '0' (
    Echo Demande des privileges administratifs ...
    Ping -n 2 127.0.0.1>NUL
    Goto UACPrompt
) Else ( Goto GotAdmin )

:UACPrompt
    Rem CHCP 1250 est utilisé pour les machines dont le 8.3 est désactivé et pour copier les accents.
    CHCP 1250>NUL
    Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\Getadmin.vbs"
    Echo UAC.ShellExecute "cmd.exe","^/c" ^& """%~s0 %~s1""", "", "runas", 1 >> "%temp%\GetAdmin.vbs"

    Cscript //Nologo "%temp%\GetAdmin.vbs"
    Exit
    ::Exit /B 1

:GotAdmin
    If Exist "%temp%\GetAdmin.vbs" (Del "%temp%\GetAdmin.vbs")
    Pushd "%CD%"
    CD /D "%~dp0"
:---------------------------------------------------------------------------------------------------------------
:---------------------------------------------------------------------------------------------------------------

If %Newcomputername%=="" Goto :ParamError
If %NewWorkgroup%=="" Set NewWorkgroup=WORKGROUP

For /F "Tokens=1*" %%a in ('SYSTEMINFO ^| FINDSTR /B /C:"Domaine:"') do Set ActualWorkgroup=%%b

Echo ---------- Parametres actuels ----------
Echo Nom de l'ordinateur : %computername%
Echo Groupe de travail   : %ActualWorkgroup%

Echo.
Echo.
Echo ----------Parametre a appliquer ----------
Echo Nom de l'ordinateur : %Newcomputername%
Echo Groupe de travail   : %NewWorkgroup%
Echo.
Echo.

:Choix
Set /p Go="Veuillez confirmer l'application des parametres ci-dessus : o/n (Oui par defaut)"
If /I "%Go%"=="" Goto :Go
If /I "%Go%"=="o" Goto :Go
If /I "%Go%"=="n" Exit
Goto Choix

:Go
wmic COMPUTERSYSTEM WHERE Name="%computername%" CALL Rename Name="%Newcomputername%" Password=null UserName=null
If errorlevel 1 Goto :Erreur

wmic COMPUTERSYSTEM WHERE Name="%computername%" CALL JoinDomainOrWorkgroup FJoinOptions=0 Name="%NewWorkgroup%" UserName=null Password=null
If errorlevel 1 Goto :Erreur

Color 0A
Echo.
Echo Vous devez redemarrer l'ordinateur pour appliquer les parametres.
Echo Appuyez sur une touche pour quitter
Pause>NUL
Exit

:ParamError
Color 0C
Echo.
Echo.
Echo.
Echo               ***** Erreur *****
Echo Le parametre Newcomputername ne doit pas etre vide.
Echo.
Echo Appuyez sur une touche pour quitter
Pause>NUL
Exit


:Erreur
Color 0C
Echo.
Echo.
Echo.
Echo Erreur lors de l'application des parametres.
Echo Veuillez effectuer les modifications manuellement.
Echo Appuyez sur une touche pour quitter
Pause>NUL
Exit