:: AllLan2Private.cmd - Par Tlem33
:: AllLan2Private est un Batch qui permet de configurer l'ensemble
:: des cartes réseau du PC en réseau privé.
::
:: Lire le fichier README.md pour plus d'informations.
::
:: Version 1.0 du 23/04/2021
:: https://github.com/Tlem33/AllLan2Private 


@Echo Off
Cls


::========================================
::      Paramètre(s)
::========================================
:: Paramètre de temporisation
Set Tempo=3
::========================================
::========================================


:: Demande des drois administrateur si nécessaire.
Net.exe session 1>NUL 2>NUL || (Powershell start-process """%~dpnx0""" "%*" -verb RunAs & Exit /b 1)


:: Ecriture du script Powershell dans un fichier temporaire
Set ScriptPS="%temp%\AllLan2Private.ps1"
Echo Get-NetConnectionProfile ^| >%ScriptPS%
Echo   Where{ $_.NetWorkCategory -ne 'Private'} ^| >>%ScriptPS%
Echo   ForEach { >>%ScriptPS%
Echo       $_ >>%ScriptPS%
Echo       $_^|Set-NetConnectionProfile -NetWorkCategory Private >>%ScriptPS%
Echo   } >>%ScriptPS%


:Go
:: Exécution du script Powershell.
Powershell.exe -executionpolicy unrestricted -command "& '%ScriptPS%'


:: Suppression du script PS temporaire
Del /F /Q %ScriptPS%


:: ^Message de fin temporisé.
Echo Fermeture automatique dans %tempo% secondes.
Ping -n %tempo% 127.0.0.1>NUL
Exit /b