:: JulieAvecWindows10.cmd - Créer par Tlem le 03/06/2015
:: JulieAvecWindows10 permet d'activer la visibilité des partages réseau aux programmes lancé avec élévation des droits.
::

@Echo Off
CLS

:---------------------------------------------------------------------------------------------------------------
:GetAdminRight
:---------------------------------------------------------------------------------------------------------------
REM --> Contrôle des permissions (Version 29/02/2016).
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> Si erreur, pas de droits Admin ...
If '%errorlevel%' NEQ '0' (
    Echo Demande des privileges administratifs ...
    Ping -n 2 127.0.0.1>NUL
    Goto UACPrompt
) Else ( Goto GotAdmin )

:UACPrompt
    Rem CHCP 1250 est utilisé pour les machines dont le 8.3 est désactivé et pour copier les accents.
    CHCP 1250>NUL
    Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\Getadmin.vbs"
    Echo UAC.ShellExecute "cmd.exe","^/c" ^& """%~s0 %~s1""", "", "runas", 1 >> "%temp%\GetAdmin.vbs"

    Cscript //Nologo "%temp%\GetAdmin.vbs"
    Exit
    ::Exit /B 1

:GotAdmin
    If Exist "%temp%\GetAdmin.vbs" (Del "%temp%\GetAdmin.vbs")
    Pushd "%CD%"
    CD /D "%~dp0"
:---------------------------------------------------------------------------------------------------------------
:---------------------------------------------------------------------------------------------------------------

%SYSTEMROOT%\System32\REG.EXE ADD "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /V "EnableLinkedConnections" /T REG_DWORD /D "1" /F
If ErrorLevel 1 (
	Color OC
	Echo.
	Echo.
	Echo Echec de L'op‚ration.
	Echo Essayez en relancant le batch avec les droits administrateur.
	Echo.
	Echo.
	Echo Appuyez sur une touche pour fermer cette fenˆtre.
	Pause>NUL
	Exit
)
Color 0A
Echo.
Echo.
Echo *******************************************************
Echo *  Un red‚marrage de l'ordinateur est n‚cessaire pour *
Echo *           prendre en compte les modifications.      *
Echo *******************************************************
Echo.
Echo.
Echo Appuyez sur une touche pour red‚marrer l'ordinateur, ou
Echo fermez cette fenˆtre pour quitter sans red‚marrer.
Pause>NUL
%SYSTEMROOT%\System32\Shutdown -r -f -t 20


:Eof